###################################################################
# Basic PYMOL script for viewing the RF1-70S termination complex. #
# Noller Laboratory, Aug 12 - 2008, John Paul Donohue             #
#                                                                 #
# Load model - change this line according to the path to the model#
#                                                                 #
load ./70S_RF1.pdb, startmodel
###################################################################

# Set defaults
cmd.bg_color('black')
set ray_shadow,off
set orthoscopic,on
set cartoon_loop_radius,0.3
set cartoon_rect_width,0.4
set cartoon_rect_length,1.5
set sphere_scale,0.2

# Define colors
set_color 23s   , [0.70, 0.70, 0.70]
set_color lprot , [0.80, 0.00, 0.80]
set_color 5s    , [0.50, 0.60, 0.85]
set_color 16s   , [0.00, 0.70, 0.90]
set_color sprot , [0.15, 0.20, 0.90]
set_color atrna , [1.00, 0.80, 0.00]
set_color ptrna , [1.00, 0.40, 0.00]
set_color etrna , [1.00, 0.00, 0.00]
set_color mrna  , [0.00, 1.00, 0.00]
set_color rf1   , [1.00, 0.80, 0.00]

# Create objects
create 23s,   startmodel and segid A23S
create 5s,    startmodel and segid A5S
create 16s,   startmodel and segid A16S
create ptrna, startmodel and segid APTN
create etrna, startmodel and segid AETN
create mrna,  startmodel and segid AMRN
create sprot, startmodel and (segid AS* or segid ATHX)
create lprot, startmodel and segid AL*
create rf1, startmodel and segid ARF1

# Color objects
color 23s, 23s
color 5s, 5s
color 16s,  16s
color ptrna, ptrna
color etrna, etrna
color mrna,  mrna
color sprot, sprot
color lprot, lprot
color rf1, rf1

# Show objects as cartoon
cmd.show_as("cartoon"   ,"23s")
cmd.show_as("cartoon"   ,"5s")
cmd.show_as("cartoon"   ,"16s")
cmd.show_as("cartoon"   ,"ptrna")
cmd.show_as("cartoon"   ,"etrna")
cmd.show_as("cartoon"   ,"mrna")
cmd.show_as("cartoon"   ,"sprot")
cmd.show_as("cartoon"   ,"lprot")
cmd.show_as("cartoon"   ,"rf1")
cmd.show_as("spheres"    ,"mg")

# Set RNA as rectangular cartoon
cartoon rectangle,23s
cartoon rectangle,5s
cartoon rectangle,16s
cartoon rectangle,ptrna
cartoon rectangle,etrna
cartoon rectangle,mrna

# Show the PxT and GGQ motifs of RF1 in red ball&stick
color red,rf1 and ( resi 184:186 or resi 228:230 )
show sticks ,rf1 and ( resi 184:186 or resi 228:230 ) and not (name c or name o or name n ) or (rf1 and resi 184 and name n)
show spheres,rf1 and ( resi 184:186 or resi 228:230 ) and not (name c or name o or name n ) or (rf1 and resi 184 and name n)

# Show P-site tRNA Ade76 in ball&stick mode.
show sticks ,ptrna and resi 76
show spheres,ptrna and resi 76
# Hide base ladder for P-tRNA Ade76
set cartoon_ladder_mode,0, ptrna and resi 76

# Show mRNA A-site codon in ball&stick mode
show sticks,  mrna and resi 19:21
show spheres, mrna and resi 19:21
set cartoon_ladder_mode,0, mrna and resi 19:21

# Hide startmodel
cmd.disable('startmodel')

# An overall view
set_view (\
    -0.025153564,   -0.028653741,   -0.999272466,\
    -0.956976235,    0.289736152,    0.015778810,\
     0.289073408,    0.956676602,   -0.034708865,\
     0.000138938,   -0.000339955, -699.878662109,\
   -77.215621948,  119.745620728,  125.377006531,\
   139.766296387, 1259.985351562,    0.000000000 )